src.pro 2.01 KB
Newer Older
1 2 3 4 5 6 7
TEMPLATE = app
TARGET = nemo-transfer-engine
DEPENDPATH += .
INCLUDEPATH += . ../lib

QT += dbus sql

8 9 10 11 12 13
packagesExist(qt5-boostable) {
  PKGCONFIG += qt5-boostable
} else {
  warning("qt5-boostable not available; startup times will be slower")
}

14
LIBS += -L../lib -lnemotransferengine-qt5
15 16

# generate adaptor code
17 18 19 20
DBUS_ADAPTORS += transferengine
transferengine.files = ../dbus/org.nemo.transferengine.xml
transferengine.header_flags = -i metatypedeclarations.h -i transferengine.h -l TransferEngine -c TransferEngineAdaptor
transferengine.source_flags = -l TransferEngine -c TransferEngineAdaptor
21 22

CONFIG += link_pkgconfig
23
PKGCONFIG += accounts-qt5 nemonotifications-qt5
24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55

# translations
TS_FILE = $$OUT_PWD/nemo-transfer-engine.ts
EE_QM = $$OUT_PWD/nemo-transfer-engine_eng_en.qm

ts.commands += lupdate $$PWD -ts $$TS_FILE
ts.CONFIG += no_check_exist
ts.output = $$TS_FILE
ts.input = .

ts_install.files = $$TS_FILE
ts_install.path = /usr/share/translations/source
ts_install.CONFIG += no_check_exist

# should add -markuntranslated "-" when proper translations are in place (or for testing)
engineering_english.commands += lrelease -idbased $$TS_FILE -qm $$EE_QM
engineering_english.CONFIG += no_check_exist
engineering_english.depends = ts
engineering_english.input = $$TS_FILE
engineering_english.output = $$EE_QM

engineering_english_install.path = /usr/share/translations
engineering_english_install.files = $$EE_QM
engineering_english_install.CONFIG += no_check_exist

QMAKE_EXTRA_TARGETS += ts engineering_english

PRE_TARGETDEPS += ts engineering_english

# Input
SOURCES += main.cpp \
    dbmanager.cpp \
56
    logging.cpp \
57 58 59 60
    transferengine.cpp

HEADERS += \
    dbmanager.h \
61
    logging.h \
62 63 64 65 66 67 68 69 70 71 72 73 74 75 76
    transferengine.h \
    transferengine_p.h

SERVICE_FILE += ../dbus/org.nemo.transferengine.service
OTHER_FILES +=  $$SERVICE_FILE \
                ../dbus/org.nemo.transferengine.xml


service.files = $$SERVICE_FILE
service.path  = /usr/share/dbus-1/services/
target.path = /usr/bin

INSTALLS += service target  ts_install engineering_english_install