Skip to content

Commit

Permalink
Browse files Browse the repository at this point in the history
Squashed 'maliit-framework/' changes from 7e6c51f..b8072bd
b8072bd Release 0.99.1
304af4b Rename dist target to release
79db892 Merge pull request #20 from attente/do-not-transfer-full
701f099 Don't require unref from GDBusProxy helpers
18064d9 Merge pull request #19 from attente/stop-using-dbus-glib
f5c8efa Enable maliit-glib tests
2dad8cb Port GLib tests to GDBus
d0dfcf2 Drop connect/disconnect GLib tests
a867e01 Bring back GLib tests
a1bbbaa Publicize MALIIT_ATTRIBUTE_EXTENSION_DATA
6b8c157 Publicize maliitattributeextensionregistry.h
b022503 Remove connection-glib
b5cf97b Don't depend on dbus-glib
a5d8630 Disconnect signal handlers
25ea290 Port to using GDBus proxies
c083bab Add D-Bus proxy helpers
159f6e5 Move all GLib-related files to maliit-glib
64fcd8d Build connection-glib and maliit-glib
866a17f Move connection-glib and maliit-glib back
45b0f90 Merge pull request #17 from attente/master
01a3b4a Generate optional GDBus bindings
60b1b10 Merge pull request #14 from Elleo/fix-plugin-iid
6fa6c9d Replace hard coded string with QPlatformInputContextFactoryInterface_iid (fixes compatibility with Qt 5.5 where this string has changed)

git-subtree-dir: maliit-framework
git-subtree-split: b8072bdcbf858214b4d0569298057beeb82e9fa7
  • Loading branch information
pvuorela committed Jun 21, 2016
1 parent 60e1f52 commit 66878e6
Show file tree
Hide file tree
Showing 41 changed files with 4,736 additions and 10 deletions.
11 changes: 10 additions & 1 deletion NEWS
@@ -1,13 +1,22 @@
{NEXT]
0.99.1
======

CHANGES SINCE 0.99.0
* Introduced Qt5 input context, replacing the one provided by Qt. Can
be enabled by CONFIG+=qt5-inputcontext
* Move maliit-glib from GTK+ input context package back into frameowrk
* Use GDBus in maliit-glib
* Allow plugin window reactive area and input method area reported to
application differ
* Fix window state to have transient hint and window type as with
Maliit 0.8x
* Made the dependency from xcb optional
* Added a CONFIG option to disable the hardware keyboard

BUG FIXES
* Clear preedit state on input context reset
* Reshow virtual keyboard when hardware keyboard disappears
* Fix bugs with Qt 5.3, Qt 5.4 and Qt 5.5

0.99.0
======
Expand Down
2 changes: 1 addition & 1 deletion VERSION
@@ -1 +1 @@
0.99.0
0.99.1
3 changes: 3 additions & 0 deletions config.pri
Expand Up @@ -7,6 +7,8 @@ MALIIT_LIB = maliit
MALIIT_SETTINGS_LIB = maliit-settings
MALIIT_HEADER = maliit
MALIIT_FRAMEWORK_HEADER = maliit/framework
# For libmaliit-glib
MALIIT_GLIB_LIB = maliit-glib

include(defines.pri)

Expand Down Expand Up @@ -194,6 +196,7 @@ defineTest(outputFile) {
MALIIT_CONNECTION_LIB \
MALIIT_SERVER_HEADER \
MALIIT_ABI_VERSION_MAJOR \
MALIIT_GLIB_LIB \

command = "sed"
for(var, variables) {
Expand Down
19 changes: 19 additions & 0 deletions dbus_interfaces/dbus_interfaces.pro
Expand Up @@ -9,3 +9,22 @@ TARGET = dummy
OTHER_FILES += \
minputmethodcontext1interface.xml \
minputmethodserver1interface.xml

glib {
include($$TOP_DIR/dbus_interfaces/dbus_interfaces.pri)

PRE_TARGETDEPS += glib_server glib_context
QMAKE_EXTRA_TARGETS += glib_server glib_context

glib_server.commands = gdbus-codegen --interface-prefix com.meego \
--generate-c-code $$TOP_DIR/maliit-glib/maliitserver \
--c-namespace Maliit \
--annotate com.meego.inputmethod.uiserver1 org.gtk.GDBus.C.Name Server \
$$DBUS_SERVER_XML

glib_context.commands = gdbus-codegen --interface-prefix com.meego \
--generate-c-code $$TOP_DIR/maliit-glib/maliitcontext \
--c-namespace Maliit \
--annotate com.meego.inputmethod.inputcontext1 org.gtk.GDBus.C.Name Context \
$$DBUS_CONTEXT_XML
}
2 changes: 1 addition & 1 deletion input-context/main.cpp
Expand Up @@ -22,7 +22,7 @@
class MaliitPlatformInputContextPlugin: public QPlatformInputContextPlugin
{
Q_OBJECT
Q_PLUGIN_METADATA(IID "org.qt-project.Qt.QPlatformInputContextFactoryInterface" FILE "maliit.json")
Q_PLUGIN_METADATA(IID QPlatformInputContextFactoryInterface_iid FILE "maliit.json")

public:
QPlatformInputContext *create(const QString&, const QStringList&);
Expand Down
17 changes: 12 additions & 5 deletions maliit-framework.pro
Expand Up @@ -16,6 +16,7 @@ include(./config.pri)
\\n\\t notests : Do not build tests \
\\n\\t nodoc : Do not build documentation\
\\n\\t local-install : Install everything underneath PREFIX, nothing to system directories reported by GTK+, Qt, DBus etc. \
\\n\\t glib : Compile GDBus bindings \
\\n\\t wayland : Compile with support for wayland \
\\n\\t qt5-inputcontext : Compile with Qt5 input context, replaces the one currently provided by Qt \
\\n\\t noxcb : Compile without xcb support \
Expand Down Expand Up @@ -46,7 +47,13 @@ wayland {
SUBDIRS += weston-protocols
}

SUBDIRS += connection src passthroughserver examples
SUBDIRS += connection

glib {
SUBDIRS += maliit-glib
}

SUBDIRS += src passthroughserver examples

qt5-inputcontext {
SUBDIRS += input-context
Expand Down Expand Up @@ -75,9 +82,9 @@ TARBALL_PATH = $$DIST_PATH$$TARBALL_SUFFIX

# The 'make dist' target
# Creates a tarball
QMAKE_EXTRA_TARGETS += dist
dist.target = dist
dist.commands += git archive HEAD --prefix=$$DIST_NAME/ | bzip2 > $$TARBALL_PATH;
dist.commands += md5sum $$TARBALL_PATH | cut -d \' \' -f 1 > $$DIST_PATH\\.md5
QMAKE_EXTRA_TARGETS += release
release.target = release
release.commands += git archive HEAD --prefix=$$DIST_NAME/ | bzip2 > $$TARBALL_PATH;
release.commands += md5sum $$TARBALL_PATH | cut -d \' \' -f 1 > $$DIST_PATH\\.md5
OTHER_FILES += NEWS README INSTALL.local
13 changes: 13 additions & 0 deletions maliit-glib/.gitignore
@@ -0,0 +1,13 @@
maliit-*.pc
maliitserver.h
maliitserver.c
maliitcontext.h
maliitcontext.c
maliitmarshallers.h
maliitmarshallers.c
Makefile.*
*.stamp
maliit/
reference/
Maliit-1.0.gir
Maliit-1.0.typelib
10 changes: 10 additions & 0 deletions maliit-glib/libmaliit-glib.pri
@@ -0,0 +1,10 @@
# Use when a .pro file requires libmaliit-glib
# The .pro file must define TOP_DIR to be a relative path
# to the top-level source/build directory, and include config.pri

LIBS += $$TOP_DIR/lib/$$maliitDynamicLib($${MALIIT_GLIB_LIB})
POST_TARGETDEPS += $$TOP_DIR/lib/$$maliitDynamicLib($${MALIIT_GLIB_LIB})
INCLUDEPATH += $$TOP_DIR

CONFIG += link_pkgconfig
PKGCONFIG += glib-2.0 gobject-2.0
41 changes: 41 additions & 0 deletions maliit-glib/maliit-docs.xml
@@ -0,0 +1,41 @@
<?xml version="1.0"?>
<!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.3//EN"
"http://www.oasis-open.org/docbook/xml/4.3/docbookx.dtd"
[
<!ENTITY % local.common.attrib "xmlns:xi CDATA #FIXED 'http://www.w3.org/2003/XInclude'">
]>
<book id="index">
<bookinfo>
<title>Maliit Reference Manual</title>
<releaseinfo>
for Maliit 1.0.
The latest version of this documentation can be found on-line at
<ulink role="online-location" url="http://www.maliit.org/docs/maliit/index.html">http://www.maliit.org/docs/maliit/index.html</ulink>.
</releaseinfo>
</bookinfo>

<chapter>
<title>Maliit</title>
<xi:include href="xml/maliitattributeextension.xml"/>
<xi:include href="xml/maliitinputmethod.xml"/>
<xi:include href="xml/maliitsettingsmanager.xml"/>
<xi:include href="xml/maliitpluginsettings.xml"/>
<xi:include href="xml/maliitsettingsentry.xml"/>
<xi:include href="xml/maliitsettingdata.xml"/>

</chapter>
<chapter id="object-tree">
<title>Object Hierarchy</title>
<xi:include href="xml/tree_index.sgml"/>
</chapter>
<index id="api-index-full">
<title>API Index</title>
<xi:include href="xml/api-index-full.xml"><xi:fallback /></xi:include>
</index>
<index id="deprecated-api-index" role="deprecated">
<title>Index of deprecated API</title>
<xi:include href="xml/api-index-deprecated.xml"><xi:fallback /></xi:include>
</index>

<xi:include href="xml/annotation-glossary.xml"><xi:fallback /></xi:include>
</book>
87 changes: 87 additions & 0 deletions maliit-glib/maliit-glib-docs.pro
@@ -0,0 +1,87 @@
TOP_DIR = ..

include(../config.pri)

TEMPLATE=lib
TARGET=dummy

GOBJECTFILES += \
maliitattributeextension.c \
maliitattributeextension.h \
maliitinputmethod.c \
maliitinputmethod.h \
maliitsettingsmanager.c \
maliitsettingsmanager.h \
maliitsettingsentry.c \
maliitsettingsentry.h \
maliitpluginsettings.c \
maliitpluginsettings.h \
maliitsettingdata.c \
maliitsettingdata.h \


LIB_DIR = $$OUT_PWD/$$TOP_DIR/lib

# The resulting html docs go into ./maliit, and the temporary build files to ./reference/
gtk_doc.name = gtk-doc
gtk_doc.CONFIG += target_predeps no_link combine
gtk_doc.output = $${OUT_PWD}/maliit/index.html
gtk_doc.clean_commands = rm -rf $${OUT_PWD}/maliit $${OUT_PWD}/reference
gtk_doc.input = GOBJECTFILES
gtk_doc.commands += mkdir -p reference &&
gtk_doc.commands += cp $$PWD/maliit-sections.txt $$PWD/maliit-docs.xml $$OUT_PWD/reference &&
gtk_doc.commands += cd reference &&
gtk_doc.commands += gtkdoc-scan --module=maliit --source-dir=$${PWD} --rebuild-types &&
gtk_doc.commands += LD_LIBRARY_PATH=\"$${LIB_DIR}\" CFLAGS=\"$$system(pkg-config --cflags gio-2.0)\" LDFLAGS=\"-L$${LIB_DIR} -l$${MALIIT_GLIB_LIB} $$system(pkg-config --libs gio-2.0)\"
gtk_doc.commands += gtkdoc-scangobj --module=maliit &&
gtk_doc.commands += gtkdoc-mkdb --module=maliit --source-dir=$${PWD} --output-format=xml && cd .. &&
gtk_doc.commands += mkdir -p maliit && cd maliit && gtkdoc-mkhtml maliit ../reference/maliit-docs.xml && cd .. &&
gtk_doc.commands += cd reference && gtkdoc-fixxref --module=maliit --module-dir=../maliit && cd ..

gir_scanner.name = g-ir-scanner
gir_scanner.CONFIG += no_link combine
gir_scanner.output = $${OUT_PWD}/Maliit-1.0.gir
gir_scanner.input = GOBJECTFILES
gir_scanner.commands += LD_LIBRARY_PATH=\"$${LIB_DIR}\" g-ir-scanner --warn-all -n Maliit --no-libtool -L$${LIB_DIR} --library=maliit-glib --include=Gio-2.0 --pkg=gio-2.0 --pkg-export=maliit-glib-1.0 --nsversion=1.0 --output=${QMAKE_FILE_OUT} ${QMAKE_FILE_IN}

GIR_FILES = $${OUT_PWD}/Maliit-1.0.gir

gir_compiler.name = g-ir-compiler
gir_compiler.CONFIG += target_predeps no_link no_check_exist
gir_compiler.output = $${OUT_PWD}/Maliit-1.0.typelib
gir_compiler.input = GIR_FILES
gir_compiler.commands += g-ir-compiler -m Maliit --output=${QMAKE_FILE_OUT} ${QMAKE_FILE_IN}

system(pkg-config gtk-doc) {
docs.files = $${OUT_PWD}/maliit
docs.path = $$DATADIR/gtk-doc/html
docs.CONFIG += no_check_exist directory

INSTALLS += docs

QMAKE_EXTRA_COMPILERS += gtk_doc
}

system(pkg-config gobject-introspection-1.0) {
GIR_DIR = $$system(pkg-config --variable=girdir gobject-introspection-1.0)
TYPELIB_DIR = $$system(pkg-config --variable=typelibdir gobject-introspection-1.0)
GIR_PREFIX = $$system(pkg-config --variable=prefix gobject-introspection-1.0)
local-install {
GIR_DIR = $$replace(GIR_DIR, $$GIR_PREFIX, $$PREFIX)
TYPELIB_DIR = $$replace(TYPELIB_DIR, $$GIR_PREFIX, $$PREFIX)
}

gir.files = $${OUT_PWD}/Maliit-1.0.gir
gir.path = $$GIR_DIR
gir.CONFIG += no_check_exist

typelib.files = $${OUT_PWD}/Maliit-1.0.typelib
typelib.path = $$TYPELIB_DIR
typelib.CONFIG += no_check_exist

INSTALLS += gir typelib

QMAKE_EXTRA_COMPILERS += gir_scanner gir_compiler
}

OTHER_FILES += maliit-sections.txt maliit-docs.xml
11 changes: 11 additions & 0 deletions maliit-glib/maliit-glib.pc.in
@@ -0,0 +1,11 @@
prefix=@PREFIX@
exec_prefix=@PREFIX@
libdir=@LIBDIR@
includedir=@INCLUDEDIR@

Name: Maliit-GLib
Description: Maliit provides a flexible and cross platform input method framework. It is usable on all MeeGo user experiences, and in other GNU/Linux distributions as well.
Version: @MALIIT_VERSION@
Requires: maliit-framework gobject-2.0 gio-2.0
Cflags: -I${includedir}/@MALIIT_HEADER@
Libs: -L${libdir} -l@MALIIT_GLIB_LIB@
102 changes: 102 additions & 0 deletions maliit-glib/maliit-glib.pro
@@ -0,0 +1,102 @@
TOP_DIR = ..

include(../config.pri)

VERSION = $$MALIIT_ABI_VERSION
TEMPLATE = lib
TARGET = $$TOP_DIR/lib/$${MALIIT_GLIB_LIB}

CONFIG += link_pkgconfig
PKGCONFIG += glib-2.0 gobject-2.0 gio-2.0 gio-unix-2.0

CONFIG -= qt

include($$TOP_DIR/connection-glib/libmaliit-connection-glib.pri)

QMAKE_CXXFLAGS_DEBUG+=-Wno-error=deprecated-declarations
QMAKE_CFLAGS_DEBUG+=-Wno-error=deprecated-declarations

HEADERSINSTALL += \
maliitattributeextension.h \
maliitattributeextensionregistry.h \
maliitinputmethod.h \
maliitsettingsmanager.h \
maliitsettingsentry.h \
maliitpluginsettings.h \
maliitsettingdata.h \
maliitbus.h \
maliitserver.h \
maliitcontext.h \

HEADERS += \
$$HEADERSINSTALL \
maliitattributeextensionprivate.h \
maliitmarshallers.h \
maliitpluginsettingsprivate.h \
maliitsettingsentryprivate.h \

SOURCES += \
maliitattributeextension.c \
maliitattributeextensionregistry.c \
maliitinputmethod.c \
maliitsettingsmanager.c \
maliitsettingsentry.c \
maliitpluginsettings.c \
maliitsettingdata.c \
maliitbus.c \
maliitserver.c \
maliitcontext.c \

target.path += $$LIBDIR

headers.path += $$INCLUDEDIR/$$MALIIT_HEADER/maliit-glib
headers.files += $$HEADERSINSTALL

outputFiles(maliit-glib.pc)

OTHER_FILES += \
maliit-glib.pc.in

install_pkgconfig.path = $${LIBDIR}/pkgconfig
install_pkgconfig.files = $$OUT_PWD/maliit-glib.pc

INSTALLS += \
target \
headers \
install_pkgconfig \

# coverage flags are off per default, but can be turned on via qmake COV_OPTION=on
for(OPTION,$$list($$lower($$COV_OPTION))){
isEqual(OPTION, on){
QMAKE_CFLAGS += -ftest-coverage -fprofile-arcs -fno-elide-constructors
LIBS += -lgcov
}
}

QMAKE_CLEAN += \
$$OBJECTS_DIR/*.gcno \
$$OBJECTS_DIR/*.gcda \
maliitmarshallers.h \
maliitmarshallers.c

OTHER_FILES += \
libmaliit-glib.pri

# generate marshallers
GLIB_GENMARSHAL_LIST += maliitmarshallers.list

OTHER_FILES += maliitmarshallers.list

glib_genmarshal_header.name = glib-genmarshal header ${QMAKE_FILE_IN}
glib_genmarshal_header.commands = glib-genmarshal --prefix=maliit_marshal --header --g-fatal-warnings ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
glib_genmarshal_header.output = ${QMAKE_FILE_IN_BASE}.h
glib_genmarshal_header.variable_out = HEADERS
glib_genmarshal_header.input = GLIB_GENMARSHAL_LIST

glib_genmarshal_source.name = glib-genmarshal source ${QMAKE_FILE_IN}
glib_genmarshal_source.commands = glib-genmarshal --prefix=maliit_marshal --body --g-fatal-warnings ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
glib_genmarshal_source.output = ${QMAKE_FILE_IN_BASE}.c
glib_genmarshal_source.variable_out = SOURCES
glib_genmarshal_source.input = GLIB_GENMARSHAL_LIST

QMAKE_EXTRA_COMPILERS += glib_genmarshal_header glib_genmarshal_source

0 comments on commit 66878e6

Please sign in to comment.