[libcontentaction] Convert to qmake.

This is more consistent with the rest of our code, and better known by most of
the people working on it. It also makes the Qt 5 port less of a pain.

data/data.pro

@@ -0,0 +1,41 @@
+TEMPLATE = aux
+
+actions.path = /usr/share/contentaction
+actions.files = \
+    tracker1.xml \
+    highlight1.xml
+INSTALLS += actions
+
+testdata.path = /opt/tests/libcontentaction/data
+testdata.files = \
+    tracker1.xml \
+    highlight1.xml \
+    hl-examples.xml
+INSTALLS += testdata
+
+applications.path = /usr/share/applications
+applications.files = defaults.list
+INSTALLS += applications
+
+backupconf.path = /usr/share/backup-framework/applications
+backupconf.files = contentaction.conf
+INSTALLS += backupconf
+
+rfs.path = /etc/osso-rfs-scripts
+rfs.files = contentaction-rfs.sh
+INSTALLS += rfs
+
+
+XML_FILES = highlight1.xml.in
+
+genreg.input = XML_FILES
+genreg.output = highlight1.xml
+genreg.commands = $$PWD/gen-regexps > regex.sed && sed -f regex.sed < ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
+genreg.name = genreg
+genreg.CONFIG += no_link target_predeps
+QMAKE_EXTRA_COMPILERS += genreg
+
+highlight1.path = /usr/share/contentaction
+highlight1.files = highlight1.xml
+highlight1.CONFIG += no_check_exist
+INSTALLS += highlight1

libcontentaction.pro

@@ -0,0 +1,10 @@
+TEMPLATE = subdirs
+SUBDIRS += src \
+           data \
+           tools \
+           tests
+
+tests.depends = src
+tools.depends = src
+
+# TODO: fix tests, doc